设为首页收藏本站

arduino 单片机机器人爱好者之家

 找回密码
 立即注册

QQ登录

只需一步,快速开始

查看: 2683|回复: 13

ESP8266 core for Arduino应用: ESP8266 AP Web Server之控制LED

[复制链接]

签到天数: 510 天

[LV.9]以坛为家II

发表于 2016-8-19 15:09:36 | 显示全部楼层 |阅读模式
本帖最后由 AllBlue 于 2017-5-16 10:03 编辑

Example : AP Web ServerESP8266 不仅可以连接网络,也可以建立自己的网络,允许其他设备连接到它,例如手机,电脑等。
该案例,展示了如何把ESP8266 变为一个接入点(AP),并提供WEB页面给客户端。

下面看下程序:
[] 纯文本查看 复制代码
#include <ESP8266WiFi.h>

//////////////////////
// WiFi Definitions //
//////////////////////
const char WiFiAPPSK[] = "12345678";

/////////////////////
// Pin Definitions //
/////////////////////
const int LED_PIN = 5;        // Thing's onboard, green LED
const int ANALOG_PIN = A0;    // The only analog pin on the esp8266
const int DIGITAL_PIN = 12;   // Digital pin to be read

WiFiServer server(80);

void setup() 
{
  initHardware();
  setupWiFi();
  server.begin();
}

void loop() 
{
  // Check if a client has connected
  WiFiClient client = server.available();
  if (!client) {
    return;
  }

  // Read the first line of the request
  String req = client.readStringUntil('\r');
  Serial.println(req);
  client.flush();
  
  // Match the request
  int val = -1; // We'll use 'val' to keep track of both the
                // request type (read/set) and value if set.
  if (req.indexOf("/led/0") != -1)
    val = 0; // Will write LED low
  else if (req.indexOf("/led/1") != -1)
    val = 1; // Will write LED high
  else if (req.indexOf("/read") != -1)
    val = -2; // Will print pin reads
  // Otherwise request will be invalid. We'll say as much in HTML

  // Set GPIO5 according to the request
  if (val >= 0)
    digitalWrite(LED_PIN, val);
  
  client.flush();

  // Prepare the response. Start with the common header:
  String s = "HTTP/1.1 200 OK\r\n";
  s += "Content-Type: text/html\r\n\r\n";
  s += "<!DOCTYPE HTML>\r\n<html>\r\n";
  // If we're setting the LED, print out a message saying we did
  if (val >= 0)
  {
    s += "LED is now ";
    s += (val)?"high":"low";
  }
  else if (val == -2)
  { // If we're reading pins, print out those values:
    s += "Analog Pin = ";
    s += String(analogRead(ANALOG_PIN));
    s += "<br>"; // Go to the next line.
    s += "Digital Pin 12 = ";
    s += String(digitalRead(DIGITAL_PIN));
  }
  else
  {
    s += "Invalid Request.<br> Try /led/1, /led/0, or /read.";
  }
  s += "</html>\n";

  // Send the response to the client
  client.print(s);
  delay(1);
  Serial.println("Client disonnected");

  // The client will actually be disconnected 
  // when the function returns and 'client' object is detroyed
}

void setupWiFi()
{
  WiFi.mode(WIFI_AP);
  
  // Do a little work to get a unique-ish name. Append the
  // last two bytes of the MAC (HEX'd) to "Thing-":
  uint8_t mac[WL_MAC_ADDR_LENGTH];
  WiFi.softAPmacAddress(mac);
  String macID = String(mac[WL_MAC_ADDR_LENGTH - 2], HEX) +
                 String(mac[WL_MAC_ADDR_LENGTH - 1], HEX);
  macID.toUpperCase();
  String AP_NameString = "ESP8266 Thing " + macID;
  
  char AP_NameChar[AP_NameString.length() + 1];
  memset(AP_NameChar, AP_NameString.length() + 1, 0);
  
  for (int i=0; i<AP_NameString.length(); i++)
    AP_NameChar[i] = AP_NameString.charAt(i);
  
  WiFi.softAP(AP_NameChar, WiFiAPPSK);

  Serial.println();
  Serial.print ( "IP address: " );
  Serial.println ( WiFi.softAPIP() );
  
}

void initHardware()
{
  Serial.begin(115200);
  pinMode(DIGITAL_PIN, INPUT_PULLUP);
  pinMode(LED_PIN, OUTPUT);
  digitalWrite(LED_PIN, LOW);
  // Don't need to set ANALOG_PIN as input, 
  // that's all it can be.
}

程序下载: ESP8266_SoftAP_Server.zip (1.75 KB, 下载次数: 12, 售价: 1 金币)

签到天数: 10 天

[LV.3]偶尔看看II

发表于 2017-2-9 12:06:21 | 显示全部楼层
ESP8266WiFi.h
找不到
回复 支持 反对

使用道具 举报

签到天数: 510 天

[LV.9]以坛为家II

 楼主| 发表于 2017-2-9 13:02:33 | 显示全部楼层
回复 支持 反对

使用道具 举报

签到天数: 10 天

[LV.3]偶尔看看II

发表于 2017-2-9 13:31:04 | 显示全部楼层
AllBlue 发表于 2017-2-9 13:02
http://www.yfrobot.com/thread-11797-1-1.html

谢谢,我研究下
回复 支持 反对

使用道具 举报

签到天数: 10 天

[LV.3]偶尔看看II

发表于 2017-2-10 20:18:42 | 显示全部楼层
折腾了几天,一直没弄成功,用1.6.13,1.8.1没法安装ESP8266库,用1.6.5,1.6.8(已经安装好库的)编译能过,但不能上传,分析了下不能上床的原因大概是因为我的是ARDUINO UNO R3扩展板的缘故,用扩展板应该如何改写呢?有没有针对扩展板的库呢?

扩展板

扩展板

芯片

芯片
回复 支持 反对

使用道具 举报

签到天数: 510 天

[LV.9]以坛为家II

 楼主| 发表于 2017-2-11 09:30:58 | 显示全部楼层
老朽 发表于 2017-2-10 20:18
折腾了几天,一直没弄成功,用1.6.13,1.8.1没法安装ESP8266库,用1.6.5,1.6.8(已经安装好库的)编译能过 ...

ESP8266 core for arduino 这系列的教程是使用arduino IDE 对ESP8266进行开发的,也就是说,ESP8266既是WIFI模块,又是主控板!这样可以理解吗?不需要arduino UNO R3。
版型选择如下图: ESP8266_版型.jpg

回复 支持 反对

使用道具 举报

签到天数: 10 天

[LV.3]偶尔看看II

发表于 2017-2-11 09:41:46 | 显示全部楼层
对,我看明白了,我现在手头是ARDUINO UNO R3的扩展板,所以,搞错了,准备重新整张ESP8266主控板试试看
回复 支持 反对

使用道具 举报

签到天数: 510 天

[LV.9]以坛为家II

 楼主| 发表于 2017-2-11 10:11:59 | 显示全部楼层
老朽 发表于 2017-2-11 09:41
对,我看明白了,我现在手头是ARDUINO UNO R3的扩展板,所以,搞错了,准备重新整张ESP8266主控板试试看

我的测试模块是nodemcu,板上有串口下载芯片,可以直接下载!
网上还有许多其他类似模块
回复 支持 反对

使用道具 举报

签到天数: 10 天

[LV.3]偶尔看看II

发表于 2017-2-11 11:17:59 | 显示全部楼层
好,谢谢,准备研究学习下WIFI视频小车,需要些啥硬件,以及需要些什么软件技术呢?
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|Archiver|手机版|小黑屋|联系我们|YFRobot ( 苏ICP备13017135  

GMT+8, 2017-11-22 11:35 , Processed in 0.142811 second(s), 29 queries .

Powered by Discuz! X3.1

© 2001-2013 Comsenz Inc.

快速回复 返回顶部 返回列表